Funciones Financieras
El manejo de las funciones financieras se convierte en una necesidad para los profesionales de diferentes áreas.
Esta funciones permiten realizar las operaciones clásicas de la matemática financiera, estudios contables, análisis económicos, etc.
Microsoft Excel te proporciona un conjunto de funciones que te permitirán realizar cálculos financieros de manera fácil y rápida.
Como el uso de cualquier función especializada, es necesario que previamente hayas adquirido unos conocimientos teóricos básicos, es por ésto que aquí no te explicaremos todas las funciones sino algunas que nos permitan realizar tareas básicas.
Flujos de amortización de préstamos
En nuestro ejemplo elaboramos un cuadro con los cálculos básicos y un flujo de amortización del préstamo.
Miremos primero el significado de algunos parámetros que nos solicitan algunas de las funciones financieras:
Tasa : es la tasa de interés del préstamo.
Nper : es le numero total de pagos del préstamo.
Va, Vp : es el valor actual del préstamo. Si se omite, se asume que es 0. Este valor tiene signo contrario al resultado de algunas funciones como pago.
Vf : es el valor futuro o saldo en efectivo después de la última cuota. Si se omite se asume que es 0.
Tipo : es un número 0 o 1 e indica el vencimiento de pagos, donde tipo 1 es para pagos anticipados y tipo 0 es para pagos vencidos.
Período: es el número de la cuota para la cual deseamos el calculo.
Debes tener en cuenta que funciones como pago, pagoint, pagoprin, pago.int.entre, pago.princ.entre y VF, entre otras, darán como resultado un valor con signo contrario al valor actual; por presentación es muy común que algunos prefieran evitar resultados negativos, por lo cual es muy usual colocar signo negativo al VA al momento de realizar los cálculos para obligar a que el resultado sea positivo.
Vamos primero a ver la sintaxis de las principales funciones, y a continuación su aplicación en el ejemplo:
| Función | Definición | Sintaxis |
| ejemplo1 |
| Pago |
Devuelve el valor de pago constante (cuota) por período.
En nuestro ejemplo, calculamos la cuota fija para los períodos anual y mensual (asumimos valor futuro de 0).
El resultado nos muestra que si queremos realizar pagos constantes anuales hasta terminar de pagar el préstamo, deberemos cancelar $6.793.918,87.
De igual modo, si deseamos realizar pagos mensuales, la cuota será de $522.652,84
| PAGO(tasa;nper;va;vf;tipo)
Así:
Anual: =PAGO(B2;B3;-B4;;B5) -->
VA se coloca negativo (-B4) para evitar que el resultado de la función de negativo.
;; significa que se omitió un valor, en este caso se omite VF, el cual Excel asume como 0.
Mensual: =PAGO(B2/12;B3*12;-B4;;B5)
Tasa se divide la tasa anual por 12 (B2/12) para hallar la tasa mensual.
nper se multiplica el número de períodos (3 años) por 12 (B3*12) para hallar el número de meses.
Igual que en el cálculo anual, se omite el VF.
|
| | |
| Pagoint |
Como ya sabes, toda cuota fija (función pago), se compone de intereses y amortización a la deuda.
La función pagoint nos calcula el pago que se hace por intereses en un período X.
En nuestro ejemplo queremos saber cuál es el pago de interés en el mes 24 (si estamos pagando bajo el modelo de cuotas fijas).
El resultado $ 151.433,74, nos dice que en la cuota No. 24 de los $522 mil que se pagan por la cuota, $151 mil son intereses y lo demás se abona a la deuda.
|
PAGOINT(tasa;período;nper;va;vf;tipo)
Nuestro cálculo queda:
=PAGOINT(B2/12;B6;B3*12;-B4;;B5)
Como en el cálculo anterior, omitimos el VF y convertimos a mensual la tasa y los períodos.
Recuerda que en B6 está el período para el cual deseamos el cálculo, en este caso 24.
|
| Pagoprin |
La función pagoprin representa el segundo componente de la cuota fija: el abono o amortización real que se hace a la deuda en un período X.
En nuestro ejemplo queremos saber cuánto se abona al crédito en la cuota número 24 (si estamos pagando bajo el modelo de cuotas fijas mensuales).
El resultado $ 371.219,10 , nos dice que en la cuota No. 24 de los $522 mil que se pagan por la cuota, $371 mil son intereses y lo demás se abona a la deuda.
|
PAGOPRIN(tasa;período;nper;va;vf;tipo)
Nuestro cálculo queda:
=PAGOPRIN(B2/12;B6;B3*12;-B4;;B5)
Como en el cálculo anterior, omitimos el VF y convertimos a mensual la tasa y los períodos.
|
| Pago.princ.entre |
Devuelve la cantidad amortizada (abonada) entre dos períodos.
Es muy parecida a la función anterior solo que esta agrupa varios períodos mientras que Pagoprin es para un solo período.
Según nuestro ejemplo, entre las cuotas uno y cinco se abonó al préstamo $ 1.068.765,35.
| =PAGO.PRINC.ENTRE(tasa;nper;vp;per_inicial;
per_final;tipo)
En el ejemplo será:
=-PAGO.PRINC.ENTRE(B2/12;B3*12;B4;B7;B8;B5)
Esta función (al igual que la siguiente) tienen unas características especiales como:
- Se le coloca el signo negativo al principio de la función y no en el capital como lo hicimos con las otras funciones.
- Es obligatorio colocar el tipo, mientras que en las otras funciones se podía dejar la casilla en blanco (omitirla) y Excel la asumía como 0.
|
| Pago.int.entre |
Devuelve la cantidad de interés generado entre dos períodos. Es decir, la cantidad pagada por intereses en varios períodos consecutivos.
Nuestro ejemplo dice que entre los períodos 1 y 5, se pagan $ 1.544.498,84 por concepto de intereses.
| =PAGO.INT.ENTRE(tasa;nper;vp;per_inicial;
per_final;tipo)
En nuestro caso quedará:
=-PAGO.INT.ENTRE(B2/12;B3*12;B4;B7;B8;B5)
|
